Ein Client-PC bzw. Server wird zukünftig für andere Zwecke benötigt. Condition WorkOffice soll von diesem Gerät deinstalliert/entfernt werden.

Schritt-für-Schritt-Anleitung

  1. Führen Sie die Datei im Unterordner "Tools" befindliche Datei workoffice uninstall.bat aus.

  2. Es öffnet sich die Eingabeaufforderung von Windows.

  3. Geben Sie den Pfad zum Root-Ordner der Condition WorkOffice-Installation an, z.B. "C:\WorkOffice" und fahren Sie mit der [Enter]-Taste fort.

  4. Alle Dateien werden per regsvr32-Befehl aus der Windows-Registrierung entfernt.

  5. Sofern das Script direkt aus dem Ordner "Tools" ausgeführt wurde, muss der Root-Ordner der WorkOffice-Installation manuell von der Festplatte entfernt werden.


Bei Bedarf kann die Script-Datei auch von Ihnen erzeugt werden. Erstellen Sie hierzu bitte eine Batch-Datei (.bat) mit dem folgenden Inhalt:

:: Prüfe auf Administratorrechte
net session >nul 2>&1
if %errorLevel% NEQ 0 (
    echo ================================================
    echo  FEHLER: Bitte starten Sie das Skript als Administrator!
    echo ================================================
    pause
    exit /b
)

@echo off
echo =====================================================
echo      WorkOffice Condition Deinstallationsscript
echo =====================================================
set /p ConditionFiles=Bitte Pfad zum Condition-Root-Ordner eingeben (z.B. C:\WorkOffice): 

rem Pfadprüfung
if not exist "%ConditionFiles%" (
    echo Fehler: Der angegebene Pfad "%ConditionFiles%" existiert nicht.
    pause
    exit /b
)

echo Beende laufenden execxp-Prozess (falls vorhanden)...
tasklist | find /i "execxp.exe" >nul 2>&1
if %ERRORLEVEL%==0 (
    taskkill /F /IM execxp.exe
    echo execxp.exe beendet.
) else (
    echo execxp.exe läuft nicht.
)

echo Deregistriere DLL-Dateien...
if exist "%ConditionFiles%\systemdateien" (
    for /f "tokens=*" %%a in ('dir /b /s "%ConditionFiles%\systemdateien"') do regsvr32 /s /u "%%a"
) else (
    echo Warnung: Ordner "systemdateien" nicht gefunden.
)

if exist "%ConditionFiles%\cmc" (
    for /f "tokens=*" %%a in ('dir /b /s "%ConditionFiles%\cmc"') do regsvr32 /s /u "%%a"
) else (
    echo Warnung: Ordner "cmc" nicht gefunden.
)

echo Lösche Registry-Einträge...
reg delete "HKLM\Software\Wow6432Node\condition.net" /f >nul 2>&1 && echo Eintrag Wow6432Node gelöscht || echo Kein Eintrag Wow6432Node gefunden.
reg delete "HKLM\Software\condition.net" /f >nul 2>&1 && echo Eintrag condition.net gelöscht || echo Kein Eintrag condition.net gefunden.

echo Entferne Programmverknüpfungen...
rmdir /s /q "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Condition WorkOffice XP" 2>nul
rmdir /s /q "%USERPROFILE%\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Condition WorkOffice XP" 2>nul
del /f /q "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp\Condition Workoffice Schnellstart.lnk" 2>nul
del /f /q "%USERPROFILE%\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\StartUp\Condition Workoffice XP Schnellstart.lnk" 2>nul

echo Entferne Programmordner "%ConditionFiles%"...
rmdir /s /q "%ConditionFiles%" && echo Programmordner entfernt || echo Fehler beim Entfernen des Programmordners.

echo =====================================================
echo          Deinstallation abgeschlossen.
echo =====================================================
pause

Betroffene Produkte

WorkOffice

Verwandte Artikel